Essays/Schwarzschild/Schwarzschild01

From J Wiki
Jump to: navigation, search


GSC0100C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

gcv          =:>@(0{])
gcvdx        =:>@(1{])
gcvdxdx      =:>@(2{])
gcvdxdxdx    =:>@(3{])
gcvdxdxdxdx  =:>@(4{])
gcvdxdxdxdxdx=:>@(5{])

mXsign  =:*/~@({.@$$1,_1:)
mXdet   =:-/ . *                       NB. see Vocabulary 'Determinant'
mXminors=:1&(|:\.)"2^:2                NB. see Vocabulary 'Outfix'

mXsign1=:(0      |:])@:((mXsign*])"2)@(0 1|:])"3
mXsign2=:(0 1    |:])@:((mXsign*])"2)@(0 1|:])"4
mXsign3=:(0 1 2  |:])@:((mXsign*])"2)@(0 1|:])"5
mXsign4=:(0 1 2 3|:])@:((mXsign*])"2)@(0 1|:])"6



L2G=:(mXsign*])"2@:mXdet@(mXminors^:3)"2@gcv
L3G=:(mXsign*])"2@:mXdet@(mXminors^:2)"2@gcv
L4G=:(mXsign*])"2@:mXdet@(mXminors^:1)"2@gcv
g4 =:              mXdet@(mXminors^:0)"2@gcv



L2gdx      =:(0      |:])@(mXminors^:2)@(0 1|:])"3@gcvdx
L2gdxdx    =:(0 1    |:])@(mXminors^:2)@(0 1|:])"4@gcvdxdx
L2gdxdxdx  =:(0 1 2  |:])@(mXminors^:2)@(0 1|:])"5@gcvdxdxdx
L2gdxdxdxdx=:(0 1 2 3|:])@(mXminors^:2)@(0 1|:])"6@gcvdxdxdxdx

L2Gdx      =:(0      |:])@:((mXsign*])@:(|."1)@|."2)@(mXminors^:2)@(0 1|:])"3@gcvdx
L2Gdxdx    =:(0 1    |:])@:((mXsign*])@:(|."1)@|."2)@(mXminors^:2)@(0 1|:])"4@gcvdxdx
L2Gdxdxdx  =:(0 1 2  |:])@:((mXsign*])@:(|."1)@|."2)@(mXminors^:2)@(0 1|:])"5@gcvdxdxdx
L2Gdxdxdxdx=:(0 1 2 3|:])@:((mXsign*])@:(|."1)@|."2)@(mXminors^:2)@(0 1|:])"6@gcvdxdxdxdx



L3gdx      =:(0      |:])@(mXminors^:1)@(0 1|:])"3@gcvdx
L3gdxdx    =:(0 1    |:])@(mXminors^:1)@(0 1|:])"4@gcvdxdx
L3gdxdxdx  =:(0 1 2  |:])@(mXminors^:1)@(0 1|:])"5@gcvdxdxdx
L3gdxdxdxdx=:(0 1 2 3|:])@(mXminors^:1)@(0 1|:])"6@gcvdxdxdxdx

L3Gdx        =:L2gdx      (mXsign1@:(+/"1@((<0 2)|:])@((1|:[)smx    ])"3 2)"5 4)L2G

L3Gdxdxt1    =:L2gdx      (mXsign2@:(+/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 3)"5 5)L2Gdx
L3Gdxdxt2    =:L2gdxdx    (mXsign2@:(+/"1@((<0 3)|:])@((1|:[)smx    ])"4 2)"6 4)L2G
L3Gdxdx      =:L3Gdxdxt1+L3Gdxdxt2

L3Gdxdxdxt1  =:L2gdx      (mXsign3@:(+/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 4)"5 6)L2Gdxdx
L3Gdxdxdxt2  =:L2gdxdx    (mXsign3@:(+/"1@((<0 3)|:])@((1|:[)smx 1|:])"4 3)"6 5)L2Gdx
L3Gdxdxdxt3  =:L2gdxdxdx  (mXsign3@:(+/"1@((<0 4)|:])@((1|:[)smx    ])"5 2)"7 4)L2G
L3Gdxdxdx    =:L3Gdxdxdxt1+((1|:])+])"3@L3Gdxdxdxt2+L3Gdxdxdxt3

L3Gdxdxdxdxt1=:L2gdx      (mXsign4@:(+/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 5)"5 7)L2Gdxdxdx
L3Gdxdxdxdxt2=:L2gdxdx    (mXsign4@:(+/"1@((<0 3)|:])@((1|:[)smx 1|:])"4 4)"6 6)L2Gdxdx
L3Gdxdxdxdxt3=:L2gdxdxdx  (mXsign4@:(+/"1@((<0 4)|:])@((1|:[)smx 1|:])"5 3)"7 5)L2Gdx
L3Gdxdxdxdxt4=:L2gdxdxdxdx(mXsign4@:(+/"1@((<0 5)|:])@((1|:[)smx    ])"6 2)"8 4)L2G
L3Gdxdxdxdx  =:L3Gdxdxdxdxt1+((1|:])+(1 3|:])+])"4@L3Gdxdxdxdxt2+((1 2|:])+(2|:])+])"4@L3Gdxdxdxdxt3+L3Gdxdxdxdxt4



L4Gdx        =:L3gdx       mXsign1@:(+/"1@((<0 2)|:])@((1|:[)smx    ])"3 2)L3G

L4Gdxdxt1    =:L3gdx       mXsign2@:(+/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 3)L3Gdx
L4Gdxdxt2    =:L3gdxdx     mXsign2@:(+/"1@((<0 3)|:])@((1|:[)smx    ])"4 2)L3G
L4Gdxdx      =:L4Gdxdxt1+L4Gdxdxt2

L4Gdxdxdxt1  =:L3gdx       mXsign3@:(+/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 4)L3Gdxdx
L4Gdxdxdxt2  =:L3gdxdx     mXsign3@:(+/"1@((<0 3)|:])@((1|:[)smx 1|:])"4 3)L3Gdx
L4Gdxdxdxt3  =:L3gdxdxdx   mXsign3@:(+/"1@((<0 4)|:])@((1|:[)smx    ])"5 2)L3G
L4Gdxdxdx    =:L4Gdxdxdxt1+((1|:])+])"3@L4Gdxdxdxt2+L4Gdxdxdxt3

L4Gdxdxdxdxt1=:L3gdx       mXsign4@:(+/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 5)L3Gdxdxdx
L4Gdxdxdxdxt2=:L3gdxdx     mXsign4@:(+/"1@((<0 3)|:])@((1|:[)smx 1|:])"4 4)L3Gdxdx
L4Gdxdxdxdxt3=:L3gdxdxdx   mXsign4@:(+/"1@((<0 4)|:])@((1|:[)smx 1|:])"5 3)L3Gdx
L4Gdxdxdxdxt4=:L3gdxdxdxdx mXsign4@:(+/"1@((<0 5)|:])@((1|:[)smx    ])"6 2)L3G
L4Gdxdxdxdx  =:L4Gdxdxdxdxt1+((1|:])+(1 3|:])+])"4@L4Gdxdxdxdxt2+((1 2|:])+(2|:])+])"4@L4Gdxdxdxdxt3+L4Gdxdxdxdxt4



g4dx        =:gcvdx       +/"1@((<0 2)|:])@((1|:[)smx    ])"3 2 L4G

g4dxdxt1    =:gcvdx       +/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 3 L4Gdx
g4dxdxt2    =:gcvdxdx     +/"1@((<0 3)|:])@((1|:[)smx    ])"4 2 L4G
g4dxdx      =:g4dxdxt1+g4dxdxt2

g4dxdxdxt1  =:gcvdx       +/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 4 L4Gdxdx
g4dxdxdxt2  =:gcvdxdx     +/"1@((<0 3)|:])@((1|:[)smx 1|:])"4 3 L4Gdx
g4dxdxdxt3  =:gcvdxdxdx   +/"1@((<0 4)|:])@((1|:[)smx    ])"5 2 L4G
g4dxdxdx    =:g4dxdxdxt1+((1|:])+])"3@g4dxdxdxt2+g4dxdxdxt3

g4dxdxdxdxt1=:gcvdx       +/"1@((<0 2)|:])@((1|:[)smx 1|:])"3 5 L4Gdxdxdx
g4dxdxdxdxt2=:gcvdxdx     +/"1@((<0 3)|:])@((1|:[)smx 1|:])"4 4 L4Gdxdx
g4dxdxdxdxt3=:gcvdxdxdx   +/"1@((<0 4)|:])@((1|:[)smx 1|:])"5 3 L4Gdx
g4dxdxdxdxt4=:gcvdxdxdxdx +/"1@((<0 5)|:])@((1|:[)smx    ])"6 2 L4G
g4dxdxdxdx  =:g4dxdxdxdxt1+((1|:])+(1 3|:])+])"4@g4dxdxdxdxt2+((1 2|:])+(2|:])+])"4@g4dxdxdxdxt3+g4dxdxdxdxt4


NB. ... execute (ijx) ...

   bTaC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTaP=:25 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   bTa0=:[L2Gdx gs
   bTa1=:(0|:[:(bTaC([L2G gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:3 (bTaC(bTa0(((2^_44);2^_15)tcm[;])"1 bTa1)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa2=:[L2Gdxdx gs
   bTa3=:(0|:[:(bTaC([L2Gdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:3 (bTaC(bTa2(((2^_44);2^_18)tcm[;])"2 bTa3)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa4=:[L2Gdxdxdx gs
   bTa5=:(0|:[:(bTaC([L2Gdxdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:3 (bTaC(bTa4(((2^_44);2^_18)tcm[;])"3 bTa5)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa6=:[L2Gdxdxdxdx gs
   bTa7=:(0|:[:(bTaC([L2Gdxdxdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:3 (bTaC(bTa6(((2^_44);2^_18)tcm[;])"4 bTa7)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa8=:[L3Gdx gs
   bTa9=:(0|:[:(bTaC([L3G gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:2 (bTaC(bTa8(((2^_44);2^_18)tcm[;])"1 bTa9)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa10=:[L3Gdxdx gs
   bTa11=:(0|:[:(bTaC([L3Gdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:2 (bTaC(bTa10(((2^_44);2^_18)tcm[;])"2 bTa11)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa12=:[L3Gdxdxdx gs
   bTa13=:(0|:[:(bTaC([L3Gdxdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:2 (bTaC(bTa12(((2^_44);2^_18)tcm[;])"3 bTa13)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa14=:[L3Gdxdxdxdx gs
   bTa15=:(0|:[:(bTaC([L3Gdxdxdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:2 (bTaC(bTa14(((2^_44);2^_18)tcm[;])"4 bTa15)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa16=:[L4Gdx gs
   bTa17=:(0|:[:(bTaC([L4G gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:1 (bTaC(bTa16(((2^_44);2^_18)tcm[;])"1 bTa17)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa18=:[L4Gdxdx gs
   bTa19=:(0|:[:(bTaC([L4Gdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:1 (bTaC(bTa18(((2^_44);2^_18)tcm[;])"2 bTa19)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa20=:[L4Gdxdxdx gs
   bTa21=:(0|:[:(bTaC([L4Gdxdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:1 (bTaC(bTa20(((2^_40);2^_18)tcm[;])"3 bTa21)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa22=:[L4Gdxdxdxdx gs
   bTa23=:(0|:[:(bTaC([L4Gdxdxdx gs)])D.1])"1
   (5 5$]) *./@(*./)"2^:1 (bTaC(bTa22(((2^_38);2^_17)tcm[;])"4 bTa23)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa24=:[g4dx gs
   bTa25=:(0|:[:(bTaC([g4 gs)])D.1])"1
   (5 5$]) (bTaC(bTa24(((2^_44);2^_18)tcm[;])"1 bTa25)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa26=:[g4dxdx gs
   bTa27=:(0|:[:(bTaC([g4dx gs)])D.1])"1
   (5 5$]) (bTaC(bTa26(((2^_44);2^_18)tcm[;])"2 bTa27)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa28=:[g4dxdxdx gs
   bTa29=:(0|:[:(bTaC([g4dxdx gs)])D.1])"1
   (5 5$]) (bTaC(bTa28(((2^_44);2^_18)tcm[;])"3 bTa29)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTa30=:[g4dxdxdxdx gs
   bTa31=:(0|:[:(bTaC([g4dxdxdx gs)])D.1])"1
   (5 5$]) (bTaC(bTa30(((2^_42);2^_17)tcm[;])"4 bTa31)bTaP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1


GSC0101C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

g1m=:(g4^_1:)


g1mdx=:_1*(g4^_2:)*"0 1 g4dx


g1mdxdxt1=:_1*(g4^_2:)*"0 2 g4dxdx
g1mdxdxt2=: 2*(g4^_3:)*"0 2 g4dx*/"1 g4dx
g1mdxdx  =:g1mdxdxt1+g1mdxdxt2


g1mdxdxdxt1=:_1*(g4^_2:)*"0 3 g4dxdxdx
g1mdxdxdxt2=: 2*(g4^_3:)*"0 3 g4dx*/"1 2 g4dxdx
g1mdxdxdxt3=:_6*(g4^_4:)*"0 3 g4dx*/"1 2 g4dx*/"1 g4dx
g1mdxdxdx  =:g1mdxdxdxt1+((0|:])+(0 2|:])+])"3@g1mdxdxdxt2+g1mdxdxdxt3


g1mdxdxdxdxt1=:_1*(g4^_2:)*"0 4 g4dxdxdxdx
g1mdxdxdxdxt2=: 2*(g4^_3:)*"0 4 g4dx*/"1 3 g4dxdxdx
g1mdxdxdxdxt3=: 2*(g4^_3:)*"0 4 g4dxdx*/"2 g4dxdx
g1mdxdxdxdxt4=:_6*(g4^_4:)*"0 4 g4dx*/"1 3 g4dx*/"1 2 g4dxdx
g1mdxdxdxdxt5=:24*(g4^_5:)*"0 4 g4dx*/"1 3 g4dx*/"1 2 g4dx*/"1 g4dx

g1mdxdxdxdxt2Sum=:((0|:])+(0 3|:])+(0 2 3|:])+])"4@g1mdxdxdxdxt2
g1mdxdxdxdxt3Sum=:(]+(0 3 1|:])+1|:])"4@g1mdxdxdxdxt3
g1mdxdxdxdxt4Sum=:((1 0|:])+(1 3 0|:])+(1|:])+(1 0 3|:])+(2 1 3|:])+])"4@g1mdxdxdxdxt4

g1mdxdxdxdx=:g1mdxdxdxdxt1+g1mdxdxdxdxt2Sum+g1mdxdxdxdxt3Sum+g1mdxdxdxdxt4Sum+g1mdxdxdxdxt5


NB. ... execute (ijx) ...

   bTbC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTbP=:25 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   bTb0=:[g1mdx gs
   bTb1=:([:(bTbC([g1m gs)])D.1])"1
   (5 5$]) (bTbC(bTb0(((2^_44);2^_18)tcm[;])"1 bTb1)bTbP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTb2=:[g1mdxdx gs
   bTb3=:(0|:[:(bTbC([g1mdx gs)])D.1])"1
   (5 5$]) (bTbC(bTb2(((2^_44);2^_18)tcm[;])"2 bTb3)bTbP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTb4=:[g1mdxdxdx gs
   bTb5=:(0|:[:(bTbC([g1mdxdx gs)])D.1])"1
   (5 5$]) (bTbC(bTb4(((2^_44);2^_18)tcm[;])"3 bTb5)bTbP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTb6=:[g1mdxdxdxdx gs
   bTb7=:(0|:[:(bTbC([g1mdxdxdx gs)])D.1])"1
   (5 5$]) (bTbC(bTb6(((2^_44);2^_17)tcm[;])"4 bTb7)bTbP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1


GSC0102C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

gcn=:g1m*"0 2 L4G


gcndxt1=:g1m  * "0 3 L4Gdx
gcndxt2=:g1mdx*/"1 2 L4G
gcndx  =:gcndxt1+(0|:])"3@gcndxt2


gcndxdxt1=:g1m    * "0 4 L4Gdxdx
gcndxdxt2=:g1mdx  */"1 3 L4Gdx
gcndxdxt3=:g1mdxdx*/"2 2 L4G
gcndxdx  =:gcndxdxt1+((0|:])+0 3|:])"4@gcndxdxt2+(0 1|:])"4@gcndxdxt3


gcndxdxdxt1=:g1m      * "0 5 L4Gdxdxdx
gcndxdxdxt2=:g1mdx    */"1 4 L4Gdxdx
gcndxdxdxt3=:g1mdxdx  */"2 3 L4Gdx
gcndxdxdxt4=:g1mdxdxdx*/"3 2 L4G

gcndxdxdxt2Sum=:((0|:])+(0 4|:])+0 3 4|:])"5@gcndxdxdxt2
gcndxdxdxt3Sum=:((0 1|:])+(0 4 1|:])+0 1 4|:])"5@gcndxdxdxt3
gcndxdxdxt4Sum=:(0 1 2|:])"5@gcndxdxdxt4

gcndxdxdx=:gcndxdxdxt1+gcndxdxdxt2Sum+gcndxdxdxt3Sum+gcndxdxdxt4Sum


gcndxdxdxdxt1=:g1m        * "0 6 L4Gdxdxdxdx
gcndxdxdxdxt2=:g1mdx      */"1 5 L4Gdxdxdx
gcndxdxdxdxt3=:g1mdxdx    */"2 4 L4Gdxdx
gcndxdxdxdxt4=:g1mdxdxdx  */"3 3 L4Gdx
gcndxdxdxdxt5=:g1mdxdxdxdx*/"4 2 L4G

gcndxdxdxdxt2Sum=:((0|:])+(0 5|:])+(0 4 5|:])+0 3 4 5|:])"6@gcndxdxdxdxt2
gcndxdxdxdxt3Sum=:((0 1|:])+(0 5 1|:])+(0 1 5|:])+(0 4 5 1|:])+(0 4 1 5|:])+0 1 4 5|:])"6@gcndxdxdxdxt3
gcndxdxdxdxt4Sum=:((0 1 2|:])+(0 5 1 2|:])+(0 1 5 2|:])+0 1 2 5|:])"6@gcndxdxdxdxt4
gcndxdxdxdxt5Sum=:(0 1 2 3|:])"6@gcndxdxdxdxt5

gcndxdxdxdx=:gcndxdxdxdxt1+gcndxdxdxdxt2Sum+gcndxdxdxdxt3Sum+gcndxdxdxdxt4Sum+gcndxdxdxdxt5Sum


NB. ... execute (ijx) ...

   bTcC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTcP=:25 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   bTc0=:[gcndx gs
   bTc1=:(0|:[:(bTcC([gcn gs)])D.1])"1
   (5 5$]) (bTcC(bTc0(((2^_43);2^_13)tcm[;])"3 bTc1)bTcP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTc2=:[gcndxdx gs
   bTc3=:(0|:[:(bTcC([gcndx gs)])D.1])"1
   (5 5$]) (bTcC(bTc2(((2^_40);2^_12)tcm[;])"4 bTc3)bTcP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTc4=:[gcndxdxdx gs
   bTc5=:(0|:[:(bTcC([gcndxdx gs)])D.1])"1
   (5 5$]) (bTcC(bTc4(((2^_36);2^_11)tcm[;])"5 bTc5)bTcP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTc6=:[gcndxdxdxdx gs
   bTc7=:(0|:[:(bTcC([gcndxdxdx gs)])D.1])"1
   (5 5$]) (bTcC(bTc6(((2^_29);2^_9)tcm[;])"6 bTc7)bTcP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1


GSC0103C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

ch1k        =:0.5*((1        |:])+(0 1        |:])-])"3@gcvdx
ch1kdx      =:0.5*((1 3      |:])+(0 1 3      |:])-])"4@gcvdxdx
ch1kdxdx    =:0.5*((1 3 4    |:])+(0 1 3 4    |:])-])"5@gcvdxdxdx
ch1kdxdxdx  =:0.5*((1 3 4 5  |:])+(0 1 3 4 5  |:])-])"6@gcvdxdxdxdx
ch1kdxdxdxdx=:0.5*((1 3 4 5 6|:])+(0 1 3 4 5 6|:])-])"7@gcvdxdxdxdxdx


NB. ... execute (ijx) ...

   bTdC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTdP=:25 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   bTd0=:[ch1kdx gs
   bTd1=:(0|:[:(bTdC([ch1k gs)])D.1])"1
   (5 5$]) (bTdC(bTd0(((2^_44);2^_18)tcm[;])"4 bTd1)bTdP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTd2=:[ch1kdxdx gs
   bTd3=:(0|:[:(bTdC([ch1kdx gs)])D.1])"1
   (5 5$]) (bTdC(bTd2(((2^_44);2^_18)tcm[;])"5 bTd3)bTdP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTd4=:[ch1kdxdxdx gs
   bTd5=:(0|:[:(bTdC([ch1kdxdx gs)])D.1])"1
   (5 5$]) (bTdC(bTd4(((2^_44);2^_18)tcm[;])"6 bTd5)bTdP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTd6=:[ch1kdxdxdxdx gs
   bTd7=:(0|:[:(bTdC([ch1kdxdxdx gs)])D.1])"1
   (5 5$]) (bTdC(bTd6(((2^_44);2^_18)tcm[;])"7 bTd7)bTdP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1


GSC0104C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

ch2k=:gcn(0|:])@:smx"2 3 ch1k


ch2kdxt1=:gcn  ((   [)smx 2|:])"2 4 ch1kdx
ch2kdxt2=:gcndx((1|:[)smx    ])"3 3 ch1k
ch2kdx  =:(0 3|:])"4@ch2kdxt1+(0 1|:])"4@ch2kdxt2


ch2kdxdxt1=:gcn    ((   [)smx 2|:])"2 5 ch1kdxdx
ch2kdxdxt2=:gcndx  ((1|:[)smx 2|:])"3 4 ch1kdx
ch2kdxdxt3=:gcndxdx((1|:[)smx    ])"4 3 ch1k
ch2kdxdx  =:(0 3 4|:])"5@ch2kdxdxt1+((0 4 1|:])+0 1 4|:])"5@ch2kdxdxt2+(0 1 2|:])"5@ch2kdxdxt3


ch2kdxdxdxt1=:gcn      ((   [)smx 2|:])"2 6 ch1kdxdxdx
ch2kdxdxdxt2=:gcndx    ((1|:[)smx 2|:])"3 5 ch1kdxdx
ch2kdxdxdxt3=:gcndxdx  ((1|:[)smx 2|:])"4 4 ch1kdx
ch2kdxdxdxt4=:gcndxdxdx((1|:[)smx    ])"5 3 ch1k

ch2kdxdxdxt1Sum=:(0 3 4 5|:])"6@ch2kdxdxdxt1
ch2kdxdxdxt2Sum=:((0 4 5 1|:])+(0 4 1 5|:])+0 1 4 5|:])"6@ch2kdxdxdxt2
ch2kdxdxdxt3Sum=:((0 5 1 2|:])+(0 1 5 2|:])+0 1 2 5|:])"6@ch2kdxdxdxt3
ch2kdxdxdxt4Sum=:(0 1 2 3|:])"6@ch2kdxdxdxt4

ch2kdxdxdx=:ch2kdxdxdxt1Sum+ch2kdxdxdxt2Sum+ch2kdxdxdxt3Sum+ch2kdxdxdxt4Sum


ch2kdxdxdxdxt1=:gcn        ((   [)smx 2|:])"2 7 ch1kdxdxdxdx
ch2kdxdxdxdxt2=:gcndx      ((1|:[)smx 2|:])"3 6 ch1kdxdxdx
ch2kdxdxdxdxt3=:gcndxdx    ((1|:[)smx 2|:])"4 5 ch1kdxdx
ch2kdxdxdxdxt4=:gcndxdxdx  ((1|:[)smx 2|:])"5 4 ch1kdx
ch2kdxdxdxdxt5=:gcndxdxdxdx((1|:[)smx    ])"6 3 ch1k

ch2kdxdxdxdxt1Sum=:(0 3 4 5 6|:])"7@ch2kdxdxdxdxt1
ch2kdxdxdxdxt2Sum=:((0 4 5 6 1|:])+(0 4 5 1 6|:])+(0 4 1 5 6|:])+0 1 4 5 6|:])"7@ch2kdxdxdxdxt2
ch2kdxdxdxdxt3Sum=:((0 5 6 1 2|:])+(0 5 1 6 2|:])+(0 5 1 2 6|:])+(0 1 5 6 2|:])+(0 1 5 2 6|:])+0 1 2 5 6|:])"7@ch2kdxdxdxdxt3
ch2kdxdxdxdxt4Sum=:((0 6 1 2 3|:])+(0 1 6 2 3|:])+(0 1 2 6 3|:])+0 1 2 3 6|:])"7@ch2kdxdxdxdxt4
ch2kdxdxdxdxt5Sum=:(0 1 2 3 4|:])"7@ch2kdxdxdxdxt5

ch2kdxdxdxdx=:ch2kdxdxdxdxt1Sum+ch2kdxdxdxdxt2Sum+ch2kdxdxdxdxt3Sum+ch2kdxdxdxdxt4Sum+ch2kdxdxdxdxt5Sum


NB. ... execute (ijx) ...

   bTeC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTeP=:25 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   bTe0=:[ch2kdx gs
   bTe1=:(0|:[:(bTeC([ch2k gs)])D.1])"1
   (5 5$]) (bTeC(bTe0(((2^_41);2^_16)tcm[;])"4 bTe1)bTeP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTe2=:[ch2kdxdx gs
   bTe3=:(0|:[:(bTeC([ch2kdx gs)])D.1])"1
   (5 5$]) (bTeC(bTe2(((2^_37);2^_12)tcm[;])"5 bTe3)bTeP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTe4=:[ch2kdxdxdx gs
   bTe5=:(0|:[:(bTeC([ch2kdxdx gs)])D.1])"1
   (5 5$]) (bTeC(bTe4(((2^_33);2^_11)tcm[;])"6 bTe5)bTeP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1

   bTe6=:[ch2kdxdxdxdx gs
   bTe7=:(0|:[:(bTeC([ch2kdxdxdx gs)])D.1])"1
   (5 5$]) (bTeC(bTe6(((2^_27);2^_8)tcm[;])"7 bTe7)bTeP)''
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1
1 1 1 1 1


GSC0105C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

B2kt1=:                    ch2kdx
B2kt2=:ch2k([smx 0|:])"3 3 ch2k

B2kt1Sum=:((1 2|:])+-@(2|:]))"4@B2kt1
B2kt2Sum=:   ((1 3|:])+-@(]))"4@B2kt2

B2k=:B2kt1Sum+B2kt2Sum


B2kdxt1=:                           ch2kdxdx
B2kdxt2=:ch2k  ((   [)smx 0|:])"3 4 ch2kdx
B2kdxt3=:ch2kdx((2|:[)smx 0|:])"4 3 ch2k

B2kdxt1Sum=:((1 2 4|:])+-@(2 4|:]))"5@B2kdxt1
B2kdxt2Sum=:     ((1 3 4|:])+-@(]))"5@B2kdxt2
B2kdxt3Sum=:  ((1 4 2|:])+-@(2|:]))"5@B2kdxt3

B2kdx=:B2kdxt1Sum+B2kdxt2Sum+B2kdxt3Sum


B2kdxdxt1=:                             ch2kdxdxdx
B2kdxdxt2=:ch2k    ((   [)smx 0|:])"3 5 ch2kdxdx
B2kdxdxt3=:ch2kdx  ((2|:[)smx 0|:])"4 4 ch2kdx
B2kdxdxt4=:ch2kdxdx((2|:[)smx 0|:])"5 3 ch2k

B2kdxdxt1Sum=:                    ((1 2 4 5|:])+-@(2 4 5|:]))"6@B2kdxdxt1
B2kdxdxt2Sum=:                           ((1 3 4 5|:])+-@(]))"6@B2kdxdxt2
B2kdxdxt3Sum=:((1 4 5 2|:])+(1 4 2 5|:])+-@(2|:])+-@(2 5|:]))"6@B2kdxdxt3
B2kdxdxt4Sum=:                      ((1 5 2 3|:])+-@(2 3|:]))"6@B2kdxdxt4

B2kdxdx=:B2kdxdxt1Sum+B2kdxdxt2Sum+B2kdxdxt3Sum+B2kdxdxt4Sum


B2kdxdxdxt1=:                               ch2kdxdxdxdx
B2kdxdxdxt2=:ch2k      ((   [)smx 0|:])"3 6 ch2kdxdxdx
B2kdxdxdxt3=:ch2kdx    ((2|:[)smx 0|:])"4 5 ch2kdxdx
B2kdxdxdxt4=:ch2kdxdx  ((2|:[)smx 0|:])"5 4 ch2kdx
B2kdxdxdxt5=:ch2kdxdxdx((2|:[)smx 0|:])"6 3 ch2k

B2kdxdxdxt1Sum=:                                                    ((1 2 4 5 6|:])+-@(2 4 5 6|:]))"7@B2kdxdxdxt1
B2kdxdxdxt2Sum=:                                                             ((1 3 4 5 6|:])+-@(]))"7@B2kdxdxdxt2
B2kdxdxdxt3Sum=:    ((1 4 5 6 2|:])+(1 4 5 2 6|:])+(1 4 2 5 6|:])+-@(2|:])+-@(2 6|:])+-@(2 5 6|:]))"7@B2kdxdxdxt3
B2kdxdxdxt4Sum=:((1 5 6 2 3|:])+(1 5 2 6 3|:])+(1 5 2 3 6|:])+-@(2 3|:])+-@(2 6 3|:])+-@(2 3 6|:]))"7@B2kdxdxdxt4
B2kdxdxdxt5Sum=:                                                      ((1 6 2 3 4|:])+-@(2 3 4|:]))"7@B2kdxdxdxt5

B2kdxdxdx=:B2kdxdxdxt1Sum+B2kdxdxdxt2Sum+B2kdxdxdxt3Sum+B2kdxdxdxt4Sum+B2kdxdxdxt5Sum


NB. ... execute (ijx) ...

   bTfC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTfP=:16 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   bTf0=:[B2kdx gs
   bTf1=:(0|:[:(bTfC([B2k gs)])D.1])"1
   (4 4$]) (bTfC(bTf0(((2^_38);2^_15)tcm[;])"5 bTf1)bTfP)''
1 1 1 1
1 1 1 1
1 1 1 1
1 1 1 1

   bTf2=:[B2kdxdx gs
   bTf3=:(0|:[:(bTfC([B2kdx gs)])D.1])"1
   (4 4$]) (bTfC(bTf2(((2^_32);2^_14)tcm[;])"6 bTf3)bTfP)''
1 1 1 1
1 1 1 1
1 1 1 1
1 1 1 1

   bTf4=:[B2kdxdxdx gs
   bTf5=:(0|:[:(bTfC([B2kdxdx gs)])D.1])"1
   (4 4$]) (bTfC(bTf4(((2^_25);2^_11)tcm[;])"7 bTf5)bTfP)''
1 1 1 1
1 1 1 1
1 1 1 1
1 1 1 1


GSC0106C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

R20i      =:+/"1@((<2 3)|:])"4@B2k
R20idx    =:+/"1@((<2 3)|:])"5@B2kdx
R20idxdx  =:+/"1@((<2 3)|:])"6@B2kdxdx
R20idxdxdx=:+/"1@((<2 3)|:])"7@B2kdxdxdx


NB. ... execute (ijx) ...

   bTgC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTgP=:16 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   bTg0=:[R20idx gs
   bTg1=:(0|:[:(bTgC([R20i gs)])D.1])"1
   (4 4$]) (bTgC(bTg0(((2^_39);2^_13)tcm[;])"3 bTg1)bTgP)''
1 1 1 1
1 1 1 1
1 1 1 1
1 1 1 1

   bTg2=:[R20idxdx gs
   bTg3=:(0|:[:(bTgC([R20idx gs)])D.1])"1
   (4 4$]) (bTgC(bTg2(((2^_33);2^_12)tcm[;])"4 bTg3)bTgP)''
1 1 1 1
1 1 1 1
1 1 1 1
1 1 1 1

   bTg4=:[R20idxdxdx gs
   bTg5=:(0|:[:(bTgC([R20idxdx gs)])D.1])"1
   (4 4$]) (bTgC(bTg4(((2^_28);2^_9)tcm[;])"5 bTg5)bTgP)''
1 1 1 1
1 1 1 1
1 1 1 1
1 1 1 1


NB. ... execute (ijx) ...

NB. ... when e is not equal to 0 the Ricci tensor is not 0 ...

   bThC=:1.5,1.5,1.2,1.2,1.5,0"_
   bThP=:100 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   (nzcount,nzmin,nzmax) ((2^_44)tsz]) (bThC([R20i gs)bThP)''
600 8.84329e_5 0.137292


NB. ... execute (ijx) ...

NB. ... when e is equal to 0 the Ricci tensor is 0 ...
NB. ... this is the Schwarzschild metric ...

   bTiC=:1.5,1.5,1.2,0,1.5,0"_
   bTiP=:100 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   (10 10$]) *./^:2"2 (0=]) ((2^_42)tsz]) (bTiC([R20i gs)bTiP)''
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1


GSC0107C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

R=:gcn+/@((<0 1)|:])@:smx"2 R20i


NB. ... execute (ijx) ...

NB. ... for this metric R=0 ...

   bTjC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTjP=:100 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   (10 10$]) (0=]) ((2^_44)tsz]) (bTjC([R gs)bTjP)''
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1


GSC0108C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

B2kcvt1=:-@((1|:])@([smx 0|:]))
B2kcvt2=:-@((0 3 4 1|:])@([smx 1|:]))
B2kcvt3=:-@((0 4 1|:])@([smx 2|:]))
B2kcvt4=:(1 0|:])@((0|:[)smx])
B2kcv  =:B2kdx+ch2k(B2kcvt1+B2kcvt2+B2kcvt3+B2kcvt4)"3 4 B2k


GSC0109C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

Bianchi=:(]+(1 3 2|:])+3 1|:])"5@B2kcv


NB. ... execute (ijx) ...

NB. ... Bianchi identity ...

   bTkC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTkP=:100 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   (10 10$]) *./^:6"5 (0=]) ((2^_41)tsz]) (bTkC([Bianchi gs)bTkP)''
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1


GSC0110C.jpg


NB. ... script Schwarzschild.ijs (continued) ...

Edivt1=:+/"1@((<1 2)|:])"3
Edivt2=:(0.5*+/"1@((<0 1)|:]))"3
Ediv  =:(Edivt1-Edivt2)@(gcn(0 2|:])@([smx 1|:])"2 3+/"1@((<2 3)|:])"5@B2kcv)


NB. ... execute (ijx) ...

NB. ... divergence of Einstein's tensor is zero ...

   bTlC=:1.5,1.5,1.2,1.2,1.5,0"_
   bTlP=:100 c4Gen 3.5 10 28,(0.1,(1p1-0.1),28),0 2p1 44,:0 2p1 20"_

   (10 10$]) *./"1 (0=]) ((2^_42)tsz]) (bTlC([Ediv gs)bTlP)''
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1
1 1 1 1 1 1 1 1 1 1



Download: File:LSC0100C.txt
Download: File:LSC0101C.txt
Download: File:LSC0102C.txt
Download: File:LSC0103C.txt
Download: File:LSC0104C.txt
Download: File:LSC0105C.txt
Download: File:LSC0106C.txt
Download: File:LSC0107C.txt
Download: File:LSC0108C.txt
Download: File:LSC0109C.txt
Download: File:LSC0110C.txt




Download MoinMoin source: File:Schwarzschild01.ijs




Next Page: Essays/Schwarzschild/Schwarzschild02
Prev Page: Essays/Schwarzschild/Schwarzschild00




Contributed by Tom Allen