Fifty Shades of J/Chapter 19

From J Wiki
Jump to: navigation, search

Table of Contents ... Glossary ... Previous Chapter ... Next Chapter

Symphony in J minor, op.31

Principal Topics

|: (transpose), . (suffix) /. (oblique), minors (of a matrix)

Is J beautiful?

Composer’s programme note: In response to a question on the forum “is J beautiful?”, Roger Hui answered as follows:

   minors =. 1&(|:\.)"2^:2

If you know mathematics, you already knew what minors are. If you know J but didn’t know mathematics, you will also now know what minors are, even if you didn’t before! For the benefit of listeners who fall between these two categories, any matrix with m rows and n columns can be transformed into a set of mn matrices each of size (m-1) by (n-1) by omitting the row and column of every element in the original matrix in turn. That much is a statement in English of the phrase above. The phrase itself forms the symphony’s motif, whose meaning unfolds movement by movement as the work progresses.

First movement : Introduction and andante syntactico. The end of the motif, has a repeat sign ^:2 indicating that the theme is to be played twice. The theme itself, to be found within the parentheses, is |:\. , that is a melody |: played with orchestration \. . Next the opening bar of the motif shows that there are two staves, in which & braces the melody to a pedal bass 1. The coda "2 adds dynamics to the main theme, indicating the level at which it is to be played. The structure of the motif should now be apparent, and the remaining movements bring into increasingly sharp focus how the four repeated musical elements |: . & " combine to make a single coherent form. As these component ideas emerge and crystallise, the work itself surges forward with a compelling, indeed inevitable momentum.

Second movement : Pastorale. The movement opens with the folk melody |: which with its easy turn of phrase is often to be heard being hummed and whistled in its native matrix environment. \. , called suffix, is perhaps not quite so well known. As the name suggests, it is associated with Suffolk, the most easterly of England’s counties, which slopes gently downwards from west to east until it disappears below the surface of the ever encroaching and unforgiving sea which is portrayed by the dot. The following illustration shows how it works, as first one part and then another withdraws from the melodic strand, in the style of the Farewell Symphony:

   ]m=.>'life';'ebbs';'away'  NB. 3 strands each played to
life                          NB. completion before the other begins
ebbs
away
   ,m
lifeebbsaway                  NB. .. then played altogether as one
   ,\.m
lifeebbsaway                  NB. .. now first three,
ebbsaway                      NB. .. then two,
away                          NB. .. then one

Gentle suffix is quite unlike the rocky coastal cliff scenery of Cornwall on the other side of the country where her cousin oblique evokes the music of the waves as they surge and then fall away in natures’s vertical polyphony :

   ,/. m            NB. flow at first ……..
l                   NB. the three melodies enter
ie                  NB. one after the other
fba                 NB. in downward progression
ebw
sa                  NB. .. then ebb
y

The music of the integers, if not the spheres, can be heard in the same fashion :

   +/. 1+i.4 4
 1  0  0  0        NB. strata of sequences increasing by 3
 2  5  0  0        NB. padded with fill items
 3  6  9  0        NB. rising in length ..
 4  7 10 13
 8 11 14  0        NB. .. and then falling
12 15  0  0
16  0  0  0

Third movement : Presto semantico. Now the number 1 is heard knocking at the door like Fate in Beethoven’s fifth. No longer is \. a gentle ebb and flow, now decline (suffix) has become a relentless forward march to the rhythm of out,fix,out,fix,out,fix,out.., as first one and then another of the underpinning strands is left out :

   1 ,\. m
ebbsaway           NB. strands are now played in all
lifeaway           NB. possible combinations, leaving out
lifeebbs           NB. one at a time

Leave them out two at time, and there are just single strands left, not three as might be expected, but only two, since those left out must be in succession :

   2 ,\. m
away               NB. leave out strands 1 and 2
life               NB. leave out strands 2 and 3

(Note : the bass line may be played with either positive or negative vibrato, that is it makes no difference if 1 is replaced by _1 or 2 by _2. )

A percussion line can be added to each strand to make , into a two-stave melody :

   (,&'!')\.m
life
ebbs
away
!!!!

ebbs
away
!!!!

away
!!!!

This illustration can be played more elegantly on the box piano <"2

   <"2 (,&'!')\.m
┌────┬────┬────┐
│life│ebbs│away│
│ebbs│away│!!!!│
│away│!!!!│    │
│!!!!│    │    │
└────┴────┴────┘

Adding a second stave to oblique transforms polyphony into modulation through a variety of keys, so in the next example theme A is in one key and themes B and C in another :

   1 2 2 ,/.m
life
ebbsaway

Fourth movement : Finale grandioso. In the final movement, the influence of Eastern music becomes apparent, since the performer is free to choose an initial foundational thread to start off each individual performance. Following this the various musical elements of the preceding movements are brought together to form a grand climax of resounding symbols. Rank 2 is the natural medium for the foundation thread, which might, for example, be

   i.3 2
0 1
2 3
4 5

but it could equally well be a matrix of any size, rank or type (character or numeric). For a rank 2 foundation thread the explicit dynamic <"2 is not strictly necessary for the first statement of the melody in which the full force of the orchestra is unleashed, slicing and transposing the rows in a crescendo which finishes at rank 3 level

   (1&(|:\.)) i.3 2
2 4
3 5

0 4
1 5

0 2
1 3

In the repeat section, each of the inner level (<"2) matrices is sliced and transposed, the latter ensuring that the original tonality of rows and columns is reinstated :

   t=. (1&(|:\.)) i.3 2
   <"2 (1&(|:\.))"2 t
┌─┬─┐
│3│2│
│5│4│
├─┼─┤
│1│0│
│5│4│
├─┼─┤
│1│0│
│3│2│
└─┴─┘

In the most popular performances, the foundation thread is rank 2, numeric and square :

   <"2 minors i.3 3
┌───┬───┬───┐
│4 5│3 5│3 4│
│7 8│6 8│6 7│
├───┼───┼───┤
│1 2│0 2│0 1│
│7 8│6 8│6 7│
├───┼───┼───┤
│1 2│0 2│0 1│
│4 5│3 5│3 4│
└───┴───┴───┘

This has led to repeated demands for the work to be performed globally wherever a popular audience for linear algebra is to be found. However, it has also been played with acclaim to audiences of a more literary inclination:

   <"2 minors 2 4$'lasttime'
┌───┬───┬───┬───┐
│ime│tme│tie│tim│
├───┼───┼───┼───┤
│ast│lst│lat│las│
└───┴───┴───┴───┘

New arrangements for different combinations of instruments and platforms are constantly in demand.

Encore ?? …

Code Summary

minors=: 1&(|:\.)"2^:2

Script

File:Fsojc19.ijs