Essays/SpaceTime2D/SpaceTime2D08

7 Riemann-Christoffel Tensor

... McCONNELL Chapter XII Section 6 ...
... Sokolnikoff Section 36 ...

7.1 Riemann-Christoffel Tensor of the Second Kind

NB. ... script SpaceTime2D.ijs (continued) ...

B2k=:((1 2|:])-2|:])"4@ch2kdv+ch2k((1 3|:[gXsmx 0|:])-[gXsmx 0|:])"3 3 ch2k

7.2 Derivative of the Riemann-Christoffel Tensor of the Second Kind

7.2.1 Derivative

NB. ... script SpaceTime2D.ijs (continued) ...

B2kdvt1=:((1 2 4|:])-2 4|:])"5@ch2kdvdv
B2kdvt2=:ch2k(((0 3 1 4|:])-0 1 4|:])@((0|:[)gXsmx 2|:])+((1 3 4|:])-])@([gXsmx 0|:]))"3 4 ch2kdv
B2kdv  =:B2kdvt1+B2kdvt2

7.2.2 Verify Derivative

NB. ... execute (ijx) ...

   p8aXd1=:((aRL'P'),<'P');<(aRL'Q'),<'Q'

   aRsetA''
   p8a1d1=.p8aXd1 B2kdv''
   mXsetV''
   p8a1d2=.p8aXd1(0|:[:(p8aXd1 B2k])D.1])"1(vGen aRR'P')
   p8a1d1((2^_6)gXteq[;])p8a1d2
1
   (p8a1d1=.0),p8a1d2=.0
0 0

7.3 Covariant Derivative of the Riemann-Christoffel Tensor of the Second Kind

NB. ... script SpaceTime2D.ijs (continued) ...

B2kcvt1=:-@(1|:[gXsmx 0|:])
B2kcvt2=:-@(0 3 4 1|:[gXsmx 1|:])
B2kcvt3=:-@(0 4 1|:[gXsmx 2|:])
B2kcvt4=:1 0|:(0|:[)gXsmx]
B2kcv  =:B2kdv+ch2k(B2kcvt1+B2kcvt2+B2kcvt3+B2kcvt4)"3 4 B2k

8 Bianchi Identity

... Sokolnikoff Section 38 ...

NB. ... execute (ijx) ...

   aRsetA''
   (((aRL'P'),<'P');<(aRL'Q'),<'Q')*./@ (*./)@((($$0:)-:(2^_19)&gXtsz@(]+(1 3 2|:])+3 1|:]))"5@B2kcv)''
1

9 Einstein Tensor

... Sokolnikoff Section 38 ...

NB. ... script SpaceTime2D.ijs (continued) ...

B1kcv =:mcv([gXsmx 3|:])"2 5 B2kcv
R20icv=:+/"1@((<2 3)|:])"5@B2kcv
R11icv=:mcn(0 2|:[gXsmx 1|:])"2 3 R20icv
Rcv   =:+/"1@((<0 1)|:])"3@R11icv

NB. ... execute (ijx) ...

   aRsetA''
   (((aRL'P'),<'P');<(aRL'Q'),<'Q')*./@ (*./)@((($$0:)-:(2^_14)&gXtsz@(]+(2 3|:])+2|:]))"5@B1kcv)''
1

NB. ... execute (ijx) ...

   aRsetA''
   (((aRL'P'),<'P');<(aRL'Q'),<'Q')*./@ (*./)@((($$0:)-:(2^_8)&gXtsz@(]+(1 3 2 0|:])-3 2 0|:]))"5@B1kcv)''
1

NB. ... execute (ijx) ...

   aRsetA''
   (((aRL'P'),<'P');<(aRL'Q'),<'Q')*./@(*./)@(+/"1@((<1 2)|:])"3@R11icv((2^_26)gXteq[;])(0.5*])"1@Rcv)''
1

10 Tangents to Coordinate Curves

10.1 v1 Coordinate Curve

... consider the tangent to the v1 coordinate curve ...

NB. ... script SpaceTime2D.ijs (continued) ...

tGntT1 =:(((0{0{])^_0.5"_),0:)"2@mcv
tGntI11=:-@(1r2*((0{0{])^_2:)"2@mcv*(0{0{0{])"3@mcvdv)+(0{0{0{])"3@ch2k%(0{0{])"2@mcv
tGntI12=:(1{0{0{])"3@ch2k%(0{0{])"2@mcv
tGntI1 =:tGntI11,"0 tGntI12

10.2 v2 Coordinate Curve

... consider the tangent to the v2 coordinate curve ...

NB. ... script SpaceTime2D.ijs (continued) ...

tGntT2 =:(0,(1{1{])^_0.5"_)"2@mcv
tGntI21=:(0{1{1{])"3@ch2k%(1{1{])"2@mcv
tGntI22=:-@(1r2*((1{1{])^_2:)"2@mcv*(1{1{1{])"3@mcvdv)+(1{1{1{])"3@ch2k%(1{1{])"2@mcv
tGntI2 =:tGntI21,"0 tGntI22

10.3 Orthogonality

NB. ... execute (ijx) ...

   p8bXd1=:((aRL'P'),<'P');<(aRL'Q'),<'Q'

   aRsetA''
   p8bXd1*./@(*./)@(0=])@((2^_41)&gXtsz)@:(+/"1)@((<0 1)|:"2 mcv gXsmx"2 tGntT1*/"1 tGntI1)''
1
   p8bXd1*./@(*./)@(0=])@((2^_42)&gXtsz)@:(+/"1)@((<0 1)|:"2 mcv gXsmx"2 tGntT2*/"1 tGntI2)''
1

Download MoinMoin source: File:SpaceTime2D08.ijs

Prev Page: Essays/SpaceTime2D/SpaceTime2D07

Contributed by Tom Allen